Я, кстати тож чего-то на LD45 накалякал, извините, забыл рассказать:
https://ldjam.com/events/ludum-dare/45/mn-master-of-nothing

Там типа такой зелёный чудик ползает по процедурно генерируемой базе роботов, спасает своих собратьев, создаёт чёрные дыры чтоб ломать генераторы и попутно заталкивать в них неугодных роботов.

Комнат мало, враги скучные, винскрина нет — такое себе получилось ИМХО.

Другие посты из этого блога

11 комментариев

Ничё так, не понятно, почему некоторые предметы (золотые гранаты) собираются, а некоторые (глаза) - нет.

Интересная фишка с чёрной дырой, а ля Магика, и почти всегда, как я её призывал, сам же туда и попадал.

Да, там надо бы задержку сделать перед формированием чёрной дыры.

Глаза - это типа ХП, собираются по мере надобности, собсна вставляются в пустые глазницы (когда противники из выбивают XD)

А, да, забыл сказать. Игру делал скорее как тест экспортера GMS2 в WEB. Так что все проблемы можно отписывать, если там звук или музыка пропали, крэшнулось чего, или управлениене фурычит.

У меня вопрос, а как делаешь карту? Я понимаю в данной игре это массив из комнат 5*5, с переходами в определенных местах. Расскажи. В интернете я нашел метод, но он построен на графах и это так замудренно, что всякий интерес пропадает разбираться в этом...

Сетка - частный случай графа, где соединены только соседние по сетке ячейки.

Человеку нужна реализация, а не математические рассуждения. Что сетка, что граф, представляются двухмерными массивами, это он и хотел узнать.

Я сетку использую. В GMS2 называется ds_grid. Можно просто двумерный массив. Комнаты все состыкованы по центру. Это самый примитив. Тогда можно вообще все комнаты перемешать. Можно делать комнаты без проходов, а потом их просто вырубать и при старте комнаты ненужные стены вместе с тайлами удалять.

Затем можно генерировать переходы до тех пор, пока "граф" не станет связным, ну то есть ты сможешь из любой точки попасть в любую. Но это может дать слишком "дырявые" карты, поэтому я делаю наоборот - генерирую список стен, т.е. много раз пытаюсь поставить стенку так чтобы "граф" оставлся связным. Это даёт карты больше похожие на лабиринты. Более того, в этом случае можно регулировать "дырявость".

Ещё есть метод вместо "стен" делать отсутсвтующие комнаты, но тогда комната по дефолту соединена с каждой соседней.

Ключи и двери тоже можно генерировать, но тут уже нужно в теорию графов погружаться и искать точки сочленения, или использовать другие алгоритмы, которые будут генерить карту "по ходу дела".

Если код интересует, то в моём случае это выглядит примерно так:

MAP_init

globalvar MAP_grid, MAP_walls, MAP_visit, MAP_x, MAP_y, MAP_direction, MAP_surface, MAP_targets, MAP_target_count, MAP_rooms;

MAP_grid = ds_grid_create(5,5);
ds_grid_clear(MAP_grid,room_proto);
MAP_visit = ds_grid_create(5,5);
ds_grid_clear(MAP_visit, 0);
MAP_walls = ds_map_create();

MAP_x=0;
MAP_y=0;
MAP_direction=0;
MAP_surface=-1;
MAP_targets=ds_map_create();
MAP_target_count=0;

MAP_rooms=ds_list_create();
ds_list_add(MAP_rooms,room_0,room_1,room_2,room_3,room_4,room_5,room_6,room_7,room_8,room_9);

Map_generate

var _w = max(argument[0],2), _h=max(argument[0],2);
ds_grid_resize(MAP_grid,_w,_h);
ds_map_clear(MAP_walls);

var l=ds_list_create(), g = ds_grid_create(_w,_h);
var len = _w*_h;
ds_grid_clear(MAP_grid,room_4);
ds_grid_clear(MAP_visit, 0);

// l - это список комнат, которые я потом перемешаю
// сперва точка старта
ds_list_add(l,room_start);
// Потом комнаты-цели, и вообще любые важные но одноразовые для уровня комнаты(магазы, алтари и т.д.)
// сколько нужно
for(var _i=0;_i<3;_i++) {
	ds_list_add(l,choose(room_target_1,room_target_2));
}

// А это массив со всеми видами комнат, я его буду перемешивать
// и накидывать из него комнат, это нужно, чтобы комнаты как можно меньше раз повторялись за одну карту.
// В идеале его размер должен быть в несколько раз больше чем количество ячеек карты
ds_list_shuffle(MAP_rooms);
var _rindx = 0;

while(ds_list_size(l)<len) {
	ds_list_add(l,MAP_rooms[| _rindx]);
	_rindx++;
	if _rindx>ds_list_size(MAP_rooms)-1 then {
		ds_list_shuffle(MAP_rooms);
		_rindx=0;
	}
}

MAP_target_count=3;
ds_map_clear(MAP_targets);

// А теперь перемешиваем их расположение
ds_list_shuffle(l);

//По порядку забиваем в массив, отмечаем точку старта игрока
var _mx = 0, _my=0;
for(var _i=0;_i<ds_list_size(l);_i++) {
	var _r = l[| _i];
	if _r==room_start then {
		MAP_x = _mx;
		MAP_y = _my;
	}
	MAP_grid[# _mx, _my]=_r;
	_mx++;
	if _mx>=ds_grid_width(MAP_grid) then {
		_mx=0;
		_my++;
	}
}

ds_list_clear(l);
// Генерим стенки, вот этот ут - как раз "дырявость карты"
len = floor(len*(0.5+random(0.5)));
randomize();
for(var i=0; i<len; i++) {
	// Выбираем случайную комнату
	var _x1=irandom(_w-1),_y1=irandom(_h-1);
	var val1 = string(_x1)+"|"+string(_y1);
	
	//Здесь будем выбирать случайное направление с учётом того что там может быть граница
	if _x1>0 then ds_list_add(l,string(_x1-1)+"|"+string(_y1));
	if _x1<_w-1 then ds_list_add(l,string(_x1+1)+"|"+string(_y1));
	if _y1>0 then ds_list_add(l,string(_x1)+"|"+string(_y1-1));
	if _y1<_h-1 then ds_list_add(l,string(_x1)+"|"+string(_y1+1));
	
	ds_list_shuffle(l);
	var val2 = l[| 0];
	ds_list_clear(l);
	
	// А это если случайно там уже есть стена = фейл-попытка
	if ds_map_exists(MAP_walls,val1+"="+val2) || ds_map_exists(MAP_walls,val2+"="+val1) then continue;
	
	// Пытаемся поставить стену
	ds_map_add(MAP_walls,val1+"="+val2,true);
	ds_map_add(MAP_walls,val2+"="+val1,true);
	
	// Сбрасываем карту посещений
	ds_grid_clear(g,0);
	// Проверяем проходимость
	mapWalk(0,0,g);
	var _min = ds_grid_get_min(g,0,0,_w,_h);
	// Если хотя бы одна комната не посещена, значть карта непроходима - убираем стенку
	if _min==0 then {
		ds_map_delete(MAP_walls,val1+"="+val2);
		ds_map_delete(MAP_walls,val2+"="+val1);
	}
}

ds_list_destroy(l);
ds_grid_destroy(g);

MAP_visit[# MAP_x, MAP_y] = 1;

Банальный обход сетки mapWalk

/// @description walk around the grid
/// @param x
/// @param y
/// @param visits
var _x = argument[0], _y=argument[1];

ds_grid_set(argument[2],_x,_y,1);

var _sl = string(_x)+"|"+string(_y)+"="+string(_x-1)+"|"+string(_y);
var _sr = string(_x)+"|"+string(_y)+"="+string(_x+1)+"|"+string(_y);
var _su = string(_x)+"|"+string(_y)+"="+string(_x)+"|"+string(_y-1);
var _sd = string(_x)+"|"+string(_y)+"="+string(_x)+"|"+string(_y+1);

if _x<ds_grid_width(MAP_grid)-1 && !ds_map_exists(MAP_walls,_sr)  && ds_grid_get(argument[2],_x+1,_y)==0 
	mapWalk(_x+1,_y,argument[2]);
if _x>0 && !ds_map_exists(MAP_walls,_sl) && ds_grid_get(argument[2],_x-1,_y)==0 
	mapWalk(_x-1,_y,argument[2]);
	
if _y<ds_grid_height(MAP_grid)-1 && !ds_map_exists(MAP_walls,_sd) && ds_grid_get(argument[2],_x,_y+1)==0 
	mapWalk(_x,_y+1,argument[2]);
if _y>0 && !ds_map_exists(MAP_walls,_su) && ds_grid_get(argument[2],_x,_y-1)==0 
	mapWalk(_x,_y-1,argument[2]);
return true;

Нижнее подчёркивание в начале имени переменной что-то значит в Гамаке или это просто такой стиль?

Такой стиль.
Капсом я пишу глобальные переменные, обычным регистром - локальные для объекта, а с подчерком - временные для блока кода. Так у меня никогда не бывает коллизии имён.

хорошая привычка, я иногда временные переменные путаю)

Написать комментарий